1.44mb-gamejam

main.zig (7785B)

---

 const raylib = @import("raylib");
 const raymath = @import("raymath");
 
 const Bullet = @import("./bullet.zig");
 const constants = @import("./constants.zig");
 const Grunt = @import("./enemy_types/grunt.zig");
 const Player = @import("./player.zig");
 const GameState = @import("./state.zig").GameState;
 const Timer = @import("./timer.zig");
 const Button = @import("./ui.zig").Button;
 const UpgradeId = @import("./upgrade.zig").UpgradeId;
 const upgrade_meta = @import("./upgrade.zig").meta;
 const upgrade_fields = @typeInfo(UpgradeId).@"enum".fields;
 
 const start_button = Button.new(
     .{ .x = 100, .y = 70 },
     .{
         .x = (constants.screen_width / 2) - 50,
         .y = (constants.screen_height / 2) - 35,
     },
 );
 
 pub fn main() !void {
     var game_state: GameState = .init();
 
     raylib.InitWindow(
         constants.screen_width,
         constants.screen_height,
         constants.screen_title,
     );
     defer raylib.CloseWindow();
 
     raylib.SetTargetFPS(constants.fps);
     while (!raylib.WindowShouldClose()) {
         switch (game_state.screen) {
             .title => {
                 raylib.BeginDrawing();
                 defer raylib.EndDrawing();
 
                 raylib.ClearBackground(raylib.RAYWHITE);
 
                 raylib.DrawRectangleV(
                     start_button.position,
                     start_button.size,
                     raylib.BLACK,
                 );
 
                 const start_button_text = "start";
                 const start_button_font_size: f32 = 18.0;
                 const start_button_text_width = raylib.MeasureText(start_button_text, start_button_font_size);
                 raylib.DrawText(
                     start_button_text,
                     @intFromFloat(start_button.position.x + (start_button.size.x - @as(f32, @floatFromInt(start_button_text_width))) / 2),
                     @intFromFloat(start_button.position.y + (start_button.size.y - start_button_font_size) / 2),
                     start_button_font_size,
                     raylib.WHITE,
                 );
 
                 if (start_button.clicked(raylib.GetMousePosition())) {
                     game_state.reset();
                 }
             },
             .upgrade => {
                 raylib.BeginDrawing();
                 defer raylib.EndDrawing();
 
                 raylib.ClearBackground(raylib.RAYWHITE);
 
                 raylib.DrawText("upgrades", 20, 40, 30, raylib.BLACK);
                 raylib.DrawText(
                     raylib.TextFormat("points: %d", game_state.enemies_killed),
                     20,
                     90,
                     20,
                     raylib.BLACK,
                 );
                 raylib.DrawText(
                     raylib.TextFormat("last run: %0.1fs", game_state.time),
                     20,
                     120,
                     18,
                     raylib.GRAY,
                 );
 
                 const row_size: raylib.Vector2 = .{ .x = 700, .y = 60 };
                 const row_spacing: f32 = 80;
                 var row_position: raylib.Vector2 = .{ .x = 50, .y = 200 };
 
                 inline for (upgrade_fields) |field| {
                     const id: UpgradeId = @enumFromInt(field.value);
                     const meta = upgrade_meta[@intFromEnum(id)];
 
                     const level = game_state.upgrades.level(id);
                     const cost = game_state.upgrades.cost(id);
                     const buyable = !game_state.upgrades.maxed(id) and game_state.enemies_killed >= cost;
 
                     const row = Button.new(row_size, row_position);
                     raylib.DrawRectangleV(
                         row.position,
                         row.size,
                         if (buyable) raylib.BLACK else raylib.GRAY,
                     );
                     raylib.DrawText(
                         meta.name.ptr,
                         @intFromFloat(row.position.x + 20),
                         @intFromFloat(row.position.y + row.size.y / 2 - 10),
                         20,
                         raylib.WHITE,
                     );
 
                     if (game_state.upgrades.maxed(id)) {
                         raylib.DrawText(
                             "MAX",
                             @intFromFloat(row.position.x + row.size.x - 120),
                             @intFromFloat(row.position.y + row.size.y / 2 - 10),
                             18,
                             raylib.WHITE,
                         );
                     } else {
                         raylib.DrawText(
                             raylib.TextFormat("lvl %d/%d  cost %d", level, meta.max_level, cost),
                             @intFromFloat(row.position.x + row.size.x - 300),
                             @intFromFloat(row.position.y + row.size.y / 2 - 10),
                             18,
                             raylib.WHITE,
                         );
                     }
 
                     if (buyable and row.clicked(raylib.GetMousePosition())) {
                         game_state.enemies_killed -= cost;
                         _ = game_state.upgrades.upgrade(id);
                     }
 
                     row_position.y += row_spacing;
                 }
 
                 const continue_button = Button.new(
                     .{ .x = 300, .y = 60 },
                     .{
                         .x = (constants.screen_width / 2) - 150,
                         .y = row_position.y + 60,
                     },
                 );
                 raylib.DrawRectangleV(
                     continue_button.position,
                     continue_button.size,
                     raylib.BLACK,
                 );
                 raylib.DrawText(
                     "continue",
                     @intFromFloat(continue_button.position.x + continue_button.size.x / 2 - 30),
                     @intFromFloat(continue_button.position.y + continue_button.size.y / 2 - 10),
                     20,
                     raylib.WHITE,
                 );
 
                 if (continue_button.clicked(raylib.GetMousePosition())) {
                     game_state.reset();
                 }
             },
             .gameplay => {
                 // -- tick
                 for (0..game_state.enemy_count) |idx| {
                     game_state.enemies[idx].move(game_state.player.position);
                 }
                 game_state.player.handleMovement();
                 game_state.tick();
 
                 // -- render
                 raylib.BeginDrawing();
                 defer raylib.EndDrawing();
 
                 raylib.ClearBackground(raylib.RAYWHITE);
 
                 // Render entities
                 game_state.player.render();
                 for (0..game_state.enemy_count) |idx| {
                     game_state.enemies[idx].render();
                 }
 
                 game_state.orphaned_bullet_pool.render(.{ .x = constants.screen_width, .y = constants.screen_height });
 
                 // Health overlay
                 const health_percent: f32 = @max(
                     0,
                     @min(1, game_state.player.health / game_state.player.max_health),
                 );
                 const damage_percent = 1 - health_percent;
                 raylib.DrawRectangle(
                     0,
                     0,
                     constants.screen_width,
                     constants.screen_height,
                     raylib.ColorAlpha(raylib.RED, damage_percent),
                 );
 
                 // Score
                 raylib.DrawText(
                     raylib.TextFormat("score: %0.0f", game_state.time),
                     10,
                     10,
                     18,
                     raylib.BLACK,
                 );
             },
         }
     }
 }